simpler fusuma

This commit is contained in:
ari committed 2026-07-28 13:43:20 -04:00
1 parent 464477cfe7
commit ad0f2e5459
7 files changed
+86 -88

No files matched your search

+2
View File
@@ -21,6 +21,8 @@
ds4-cuda = final.callPackage ../../pkgs/ds4 { backend = "cuda"; };
# Touchscreen gesture bridge for niri, see pkgs/niri-touchscreen-gestures.
niri-touchscreen-gestures = final.callPackage ../../pkgs/niri-touchscreen-gestures { };
# Fusuma + niri plugin, see pkgs/fusuma.
fusuma = final.callPackage ../../pkgs/fusuma { };
})
(final: prev: {
pythonPackagesExtensions = prev.pythonPackagesExtensions ++ [
-59
View File
@@ -1,59 +0,0 @@
{ config, lib, pkgs, ... }:
let
cfg = config.skyg.nixos.common.fusuma;
configFile =
if cfg.configFile != null then
cfg.configFile
else
pkgs.writeText "fusuma-config.yml" (lib.generators.toYAML { } cfg.settings);
in
{
options.skyg.nixos.common.fusuma = {
enable = lib.mkEnableOption "Fusuma multi-touch gesture daemon (niri + per-app support)";
package = lib.mkPackageOption pkgs "fusuma" { };
settings = lib.mkOption {
type = with lib.types; attrsOf anything;
default = { };
example = {
swipe."3".left.command = "niri msg action FocusColumnRight";
app.zed = {
match.class = "dev.zed.Zed";
swipe."2".left.keypress = { ALT = "press"; LEFT = "press"; };
};
};
description = ''
Fusuma configuration as a Nix attribute set.
Converted to YAML and passed to the daemon.
'';
};
configFile = lib.mkOption {
type = lib.types.nullOr lib.types.path;
default = null;
description = "Path to an existing Fusuma config.yml (overrides generated settings)";
};
};
config = lib.mkIf cfg.enable {
environment.systemPackages = [ cfg.package ];
# Ensure the user can read raw input devices
users.users.${config.skyg.user.name}.extraGroups = lib.mkIf config.skyg.user.enable [ "input" ];
systemd.user.services.fusuma = {
description = "Fusuma multi-touch gesture daemon";
partOf = [ "graphical-session.target" ];
after = [ "graphical-session.target" ];
wantedBy = [ "graphical-session.target" ];
serviceConfig = {
ExecStart = "${lib.getExe cfg.package} --daemon --config ${configFile}";
Restart = "on-failure";
RestartSec = 2;
};
};
};
}