Files
nixos-setup/modules/home/default.nix
T
2024-08-18 20:50:52 -04:00

66 lines
1.5 KiB
Nix

{ stateVersion }:
let
makeCommonGitConfigs = (import ./git.nix).makeCommonGitConfigs;
programsModule = (import ./programs.nix);
servicesModule = (import ./services.nix);
fontsModule = (import ./fonts.nix);
homeModule = {
stateVersion = stateVersion;
shellAliases = {
cat = "bat";
};
};
in
{
makeRootUser = { hostName }: { pkgs, ... }: {
home = homeModule;
programs = (programsModule { pkgs = pkgs; }) // {
git = (makeCommonGitConfigs {
userName = "root";
userEmail = "root@${hostName}";
extraGitConfigs = [ ];
});
};
services = servicesModule { pkgs = pkgs; };
fonts = fontsModule;
};
makeCommonUser =
{ enableDevelopmentKit ? false
, fullName
, email
, extraGitConfigs ? [ ]
, name
, ...
}: { pkgs, ... }: {
fonts = fontsModule;
home = homeModule // {
username = name;
homeDirectory = "/home/${name}";
packages = with pkgs;
[
jq
nixpkgs-fmt
ipfetch
nixd
htop
]
++ (if enableDevelopmentKit then [
devenv
devbox
terraform
kubectl
] else
[ ]);
};
programs = (programsModule { pkgs = pkgs; }) // {
git = (makeCommonGitConfigs {
userName = fullName;
userEmail = email;
extraGitConfigs = extraGitConfigs;
});
};
services = servicesModule { pkgs = pkgs; };
};
}