Files
skygqts/package.nix
T
2026-10-27 13:42:22 -04:00

63 lines
1.4 KiB
Nix

{
lib,
stdenvNoCC,
makeWrapper,
qt6,
quickshell,
nushell,
curl,
grim,
}:
stdenvNoCC.mkDerivation {
pname = "skygqts";
version = "0.1.0";
src = lib.fileset.toSource {
root = ./.;
fileset = lib.fileset.unions [
./app-carousel
./workspace-manager
./workspace-badge
./skygqts.nu
];
};
nativeBuildInputs = [
makeWrapper
qt6.qtshadertools
];
# Only qsb is needed from Qt. Quickshell does the Qt wrapping.
dontWrapQtApps = true;
# Qt needs shaders compiled to .qsb before it can load them.
buildPhase = ''
runHook preBuild
for shader in workspace-manager/shaders/*.vert workspace-manager/shaders/*.frag; do
qsb --glsl "100 es,120,150" --hlsl 50 --msl 12 -o "$shader.qsb" "$shader"
done
runHook postBuild
'';
installPhase = ''
runHook preInstall
mkdir -p $out/share/skygqts
cp -r app-carousel $out/share/skygqts/
cp -r workspace-manager $out/share/skygqts/
cp -r workspace-badge $out/share/skygqts/
cp skygqts.nu $out/share/skygqts/
mkdir -p $out/bin
makeWrapper ${lib.getExe nushell} $out/bin/skygqts \
--add-flags "$out/share/skygqts/skygqts.nu" \
--prefix PATH : ${lib.makeBinPath [ quickshell curl grim ]}
runHook postInstall
'';
meta = {
description = "Quickshell SKYG Apps";
platforms = lib.platforms.linux;
mainProgram = "skygqts";
};
}