Files
skyg-linux-tracker/nix/package.nix
T

42 lines
1.2 KiB
Nix

{ lib, rustPlatform, pkg-config, cmake, systemd }:
rustPlatform.buildRustPackage {
pname = "skyg-linux-tracker";
version = (lib.importTOML ../Cargo.toml).package.version;
src = lib.fileset.toSource {
root = ../.;
fileset = lib.fileset.unions [
../Cargo.toml
../Cargo.lock
../config.example.toml
../migrations
../src
../tests
../examples
../docs/openapi.json
];
};
cargoLock.lockFile = ../Cargo.lock;
# cmake: aws-lc-sys. Live-journal tests are #[ignore], so the sandbox runs
# the rest of the suite.
nativeBuildInputs = [ pkg-config cmake ];
buildInputs = [ systemd ];
# These two need host state the build sandbox lacks: a root-owned /usr, and a
# CA bundle for the reqwest client. They run under cargo test outside Nix.
checkFlags = [
"--skip=db::tests::cli_owner_check_uses_file_then_parent_and_allows_missing_dir"
"--skip=telemetry::tests::exporters_build_for_both_protocols"
];
meta = {
description = "Read-only Linux system monitor: systemd, journald and Docker over REST, MCP and OpenTelemetry";
license = lib.licenses.mit;
mainProgram = "slinuxm";
platforms = lib.platforms.linux;
};
}